//AKJ to pattern femalemalenonbinary

(
SynthDef(\akj1, {
	arg freq=300, amp=0.1, out=0, gate=1;
	var snd, env;

	freq = [freq,freq*1.01];

	snd = LFPar.ar(freq) * 0.3
	+ (LFTri.ar(freq*16/19, mul:0.3))
	+ (Pulse.ar(freq*21/40, mul:0.1))
	+ (SinOsc.ar(freq/8.01, mul:4).clip2(0.3));
	

	env = Linen.kr(gate, attackTime:1, releaseTime:3, doneAction:2);
	snd = Splay.ar(snd);
	snd = snd * env * amp;
	Out.ar(out, snd);
}).add;
)

(
SynthDef(\akjbz, {
	arg freq=300, amp=0.1, out=0, gate=1;
	var snd, env;

	//freq = [freq, freq*2.02, freq*1.98, freq];
	snd = SinOsc.ar(freq/4, mul:0.7)!2;
	//snd = snd * [1, 0.1, 0.1, 1];
	snd = snd * Lag.ar(LFPulse.ar(freq/8.02, 0.5).range(1,0),0.005);
	snd = snd.softclip(0.5) * 1.5 ;
	
	env = Linen.kr(gate, 0,1,0, 2);
	//snd = (snd + (snd.wrap2 * 0.54)).softclip;

	snd = snd * env * amp;
	
	Splay.ar(snd);
	Out.ar(out, snd);
	//LFPulse.ar(0.275, width:0.25).range(0,1);

}).add
)

(
SynthDef(\click1, {
	arg out=0, gate=1, freq=440, amp=0.1, releaseTime=0.1;
	var snd, env;

	snd = LFPulse.ar([freq, freq * 2], width: LFNoise1.ar(0.1).exprange(0.001,0.004));
	snd = snd + (WhiteNoise.ar(1) * snd);
	snd = HPF.ar(snd, 200);
    //snd = Limiter.ar((snd * 5));

	env = EnvGen.ar(Env.perc(0,releaseTime));
	
	snd = snd * env * amp * Linen.kr(gate, 0, 1, releaseTime, 2);
	snd = Splay.ar(snd);
	Out.ar(out, snd);
}).add
)


// -- disonant chord + click + bazz -------------------------------
TempoClock.tempo=1
// disonchord
Pdef(\akj1p).play;
(
Pbindef(\akj1p, *[
	instrument: \akj1,
	freq:300,
	dur:5,
	legato: 1,
	amp: 1
]))
Pdef(\akj1p).stop;


// click
Pdef(\clickp).play(quant:4);
Pdef(\clickp).stop(quant:4);
(
Pbindef(\clickp, *[
	instrument: \click1,
	dur: Pseq([Pseq([1,2,3]/8, 2), Pseq([1,2,1,2,1,1]/8,3), Pseq([1]/8, 4), Pseq([1]/16, 2), ],inf),
	//dur: Pseq([Pn(1/8, 31), Rest(1/8)],inf),
	amp: Prand([5,7,8,9]/10, inf),
	releaseTime: 0.3,
	freq:1
	
])
)

// deep bass --
Pdef(\akjbp).play(quant:4)
(
Pbindef(\akjbp, *[
	instrument: \akjbz,
	freq: 300,
	dur: 8,
	amp: 0.5,
	legato: 0.20
])
)
Pdef(\akjbp).stop

// ----------------------------------------------------------------------------