algoforte03a/MELLOW_PULSES.scd

// ----------------------------------------------------------------------------
// MELLOW PULSES
(
~tf.stop; ~tf = fork{ loop{ TempoClock.default.tempo = 0.09.rand + 0.95; 1.wait; }} ;

~fxFeedDelay1.set(\feedback, 0.8);
~fxJPverb1.set(\wet, 0.8);

// load Pbinds
~mellow_pulses = Ppar([

	Pbind(*[ type: \midi, midicmd: \noteOn, midiout: m, chan: 1,
		amp: Ptuple([ Pwhite(0.6,0.9), Pwhite(0.6,0.9) ], inf) * Pseg([0.9, 0.76, 0.9], [0.1,59.9], \lin, inf),
		legato: 1,
		scale: Scale.minor,
		dur: Pseq([5,6,4,7,3],inf),
		degree:(0..7) * Pxrand((4..2), inf),
		octave: Prand([[5,4,6],[4,5],[5,6],5],inf) - 1,
		mtranspose: Prand([0,2,4],inf),
		ctranspose: Plet(\ctrans, Pdup(8, Pseq([0, -5, 2, -3, 4, -1], 1) - 1)),
	]),

	Pbind(*[ instrument: \pulseTriSaw,
		amp: Pseg([0.6, 0.9, 0.6], 60, \lin, inf) * 1,
		legato: 0.1,
		scale: Scale.minor(\pythagorean),
		dur:1.5,
		degree: 0,
		octave: 6,
		sawamp: Pseg([0,1,0],50,\lin,inf),
		atk:0,
		dec:0.2,
		sus:0.3 * Pseg([0,1,0], 40, \sqr, inf),
		rls:5,
		lpf: Pseg([3,20,3],40,\sqr, inf), //Pwhite(3,20),
		pan:Pwhite(-1,1),
		out: ~fxJPverbBus1,
		ctranspose: Pget(\ctrans, default:0, repeats: 8 * 6 * 1 * (5/1.5))
	]),

	Pbind(*[ instrument: \softSaw,
		scale: Scale.minor(\pythagorean),
		dur:6,
		attackTime: 3,
		releaseTime: 3,
		legato: 1.2,
		degree: Pseq([0,3], inf) + [0,4],
		octave: 3,
		amp: 0.09 * Pseg([0,0,1,1,0],60,\sqr),
		out: ~fxFeedDelayBus1,
		ctranspose: Pget(\ctrans, default:0, repeats: 144) ])

]);

fork {

	"--- start chords, pulses and deep soft Saw ... ".postln;
	~mpulses = Plambda( ~mellow_pulses).play(quant:1);

	120.wait;

	"--- start glitches ... ".postln;
	Pbindef(\glitch2, *[
		instrument: \smpPlay,
		bufnum: Pdup(1,Pxrand([
			~getSmp.("Loop_049"), ~getSmp.("Loop_048"), ~getSmp.("Loop_050"),
			~getSmp.("Loop_053"), ~getSmp.("Loop_052"), ~getSmp.("Loop_047")
		],inf)),

		legato:Pwhite(0,0.2),
		spos: Pwhite(0.1,2.5),
		dur:Pn(6, 20),
		pan:Pwhite(-1.0,1.0),
		amp:0.08,
		out: 0, // ~fxFeedDelayBus1,
		lpffreq: 14000, hpffreq: 500,
	]
	).play(quant:2);

	120.wait;

	"end. ".postln;

}
)