
Ndef(\gg1).play;
Ndef(\gg1).fadeTime = 10;
(
Ndef(\gg1, {
	var snd, freq=Lag.kr(LFNoise0.kr(0.1).range(58,60), 3);
	freq = [freq * 1, freq];
	snd = Gendy1.ar(minfreq:(freq * 0.01) * [102,189,192,89],
					maxfreq:(freq * 0.01) * [89,192,189,103],
					mul:0.7);
	snd = Splay.ar(snd);
	snd = snd * LFTri.ar(LFNoise1.kr(0.2).range(2,30)).range(0.5,1);
	snd = snd + (snd.clip2(LFNoise1.kr(0.1).range(0.3,0.05)) * 4);
	snd = LPF.ar(snd, LFNoise1.kr(0.3).exprange(100,200));
	snd = CombN.ar(snd, 1,
		[0.77,0.44] * LFNoise1.kr(0.1).range(0.99,1.02),
		10) + snd;
	snd = LFPar.ar(freq * [1.01,0.99]) * 0.5 + snd ;
	snd = snd * -12.dbamp;
	snd = LeakDC.ar(snd);
	snd = snd.softclip(0.9) * 1 ;
})
)


